Back to EDS Strategies

 

 

180s Buy

! Based upon strategies from "Hit and Run Trading" by Jeff Cooper. Copyright M. Gordon Publishing.
! 180's - Buys - from Hit and Run Trading by Jeff Cooper.
! On Day 1 , the stock must close in the bottom 25% of its daily range.
! OnDay 2, the stock must close in the top 25% of its range.
! The stocks price must close greater than both its 10 and 50 day MA on Day 2 only.
! Buy 1/8 point above the day 2 high, on day 3.

AboveMA if val([close],1)>[ST MA] and val([close],1)>[IT MA].

BuyPoint if [close]>= val([high],1)+0.125.

Range is val([high],2) - val([low],2).
low is Range*0.25.

Range2 is val([high],1) - val([low],1).
high is Range2*0.75.

Bottom25 is low + val([low],2).
Close2DaysAgo if val([close],2)<=Bottom25.

!!!Example stock A on 09/07/2001

Top25 is high + val([low],1).
CloseYesterday if val([close],1)>=Top25.

!!!Example stock ABS on 09/07/2001

Buy180 if Close2DaysAgo and CloseYesterday and AboveMA and BuyPoint.

!!!Example stock DUK on 09/07/2001

Return to Top of Page

180s Short

! Based upon strategies from "Hit and Run Trading" by Jeff Cooper. Copyright M. Gordon Publishing.
! 180's - short - from Hit and Run Trading by Jeff Cooper.
! On day 1 the stock must close in the top 25% of its range.
! On day 2 the stock must close in the bottom 25% of its range.
! The stocks price must close under both it 10 and 50 day MA on day 2 only.
! Sell short 1/8 point under the 2 day low, on day 3.

Range is val([high],2) - val([low],2).
high is Range*0.75.

Top25 is high+val([low],2).
Close2DaysAgo if val([close],2) >=Top25.

Range2 is val([high],1) - val([low],1).
low is Range2*0.25.
Bottom25 is low+val([low],1).
CloseYesterday if val([close],1) <=Bottom25.

BelowMA if val([close],1)<[ST MA] and val([close],1)<[IT MA].

SellPoint is [close]<= val([low],1)-0.125.

SellShort180 if Close2DaysAgo and CloseYesterday and BelowMA and SellPoint.

!!!Example stock WPI on 09/07/2001

Return to Top of Page

5-Day Momentum Buy

! The 5-Day Momentum Method. Copyright 1997, M. Gordon Publishing, Inc.
! For Buys
! The ADX must be 35 or higher and the +DI greater than the -DI.
! The stock's price must close above 50.
! The Stochastic must be 40 or under.
! Tomorrow buy 1/16 point above today's high. If you are not filled,
! you will look to buy the next day.


!ADX35DirMovPlus if [ADX]>=35 and [DirMov]>0.
!MinPrice if [Close]>50.
!Stochastic if [Stochastic]<=40.
!change to 25 ,20 and 30
ADX35DirMovPlus if [ADX]>=25 and [DirMov]>0.
MinPrice if [Close]>20.
Stochastic if [Stochastic]<=30.
BuyLong if ADX35DirMovPlus and MinPrice and Stochastic.

!!!Example stock CBE on 09/07/2001

!allbad if 1=1.
twoup if ([close]>Val([close],1) and Val([close],1)>Val([close],2)).
allbad if twoup or [close]<[open].

!!!Example stock AA on 09/07/2001

Return to Top of Page

Boomer Buy

! Based upon strategies from "Hit and Run Trading" by Jeff Cooper. Copyright M. Gordon Publishing.
! Boomers - Buys - from Hit and Run Trading by Jeff Cooper.
! ADX must be more than 30 and DirMov must be positive.
! Day 2's high must be less than or equal to day 1's high and its low must be greater than or equal to
! Day 1's low.
! Day 3's high must be less than or equal to day 2's high and its low must be greater than or equal to
! Day 2's low.
! On day four only buy 1/8 above the day 3 high.

Adx30DirMovUp if [adx] > 30 and [DirMov] > 0.

InsideDay1 if Val([high], 2) <= Val([high], 3) and Val([low], 2) >= Val([low], 3).
InsideDay2 if Val([high], 1) <= Val([high], 2) and Val([low], 1) >= Val([low], 2).

Day4Only if [close] >= Val([high], 1) + 0.125.

BoomerBuy if Adx30DirMovUp and Insideday1 and InsideDay2 and Day4Only.

!!!Example stock FDP on 09/07/2001

Return to Top of Page

 

Boomer Short

! Based upon strategies from "Hit and Run Trading" by Jeff Cooper. Copyright M. Gordon Publishing.
! Boomers - Short - from Hit and Run Trading by Jeff Cooper.
! ADX must be more than 30 and DirMov must be negative.
! Day 2's high must be less than or equal to day 1's high and its low must be greater than or equal to
! Day 1's low.
! Day 3's high must be less than or equal to day 2's high and its low must be greater than or equal to
! Day 2's low.
! On day four only sell 1/8 below the day 3 low.

Adx30DirMovDown if [adx] > 30 and [DirMov] < 0.

InsideDay1 if Val([high], 2) <= Val([high], 3) and Val([low], 2) >= Val([low], 3).
InsideDay2 if Val([high], 1) <= Val([high], 2) and Val([low], 1) >= Val([low], 2).

Day4Only if [close] <= Val([low], 1) - 0.125.

BoomerShort if Adx30DirMovDown and Insideday1 and InsideDay2 and Day4Only.

!!!Example stock IBP on 09/07/2001

Return to Top of Page

Expansion Pivot Buys

! Based upon strategies from "Hit and Run Trading" by Jeff Cooper. Copyright M. Gordon Publishing.
! Expansion Pivots - Buy - from Hit and Run Trading by Jeff Cooper.
! Todays Range is greater than the daily range of the past nine Trading days. Either yesterday or today
! the stock is Trading at or below the 50 day MA and explodes higher. On the next Trading day place a
! buy 1/8 above the explosion day high.

TodaysRange is Val([high], 1) - Val([low], 1).

PriceRange9daysago is HighResult(TodaysRange,10,2).

GoodPriceRange if TodaysRange >= PriceRange9daysago.

Above50dITMA if Val([close], 1) >= Val([IT MA], 1) or Val([close], 2) >= Val([IT MA], 2) and Val([high], 1) > Val([high], 2).

BuyNow if [close] >Val([high], 1) + 0.125.

ExpansionPivotsBuy if GoodPriceRange and Above50dITMA and BuyNow.

!!!Example stock HE on 09/10/01

Return to Top of Page

Expansion Pivot Shorts

! Based upon strategies from "Hit and Run Trading" by Jeff Cooper. Copyright M. Gordon Publishing.
! Expansion Pivots- Short - from Hit and Run Trading by Jeff Cooper.
! Todays range is greater than the daily range of the past nine Trading days. Either yesterday or today
! the stock is Trading at or above the 50 day MA and explodes lower. On the next Trading day sell 1/8
! below the explosion day low. 

TodaysRange is Val([high], 1) - Val([low], 1).

PriceRange9daysago is HighResult(TodaysRange, 10,2).

GoodPriceRange if TodaysRange >= PriceRange9daysago.

Above50dITMA if VAL([close],2)>VAL([IT MA],2) and Val([close], 1) < Val([IT MA], 1).

!Above50dITMA if Val([close], 1) <= Val([IT MA], 1) or Val([close], 2) <= Val([IT MA], 2) and Val([high], 1) < Val([high], 2).

SellNow if [close] < Val([low], 1) + 0.125.

ExpansionPivotsShort if GoodPriceRange and Above50dITMA and SellNow.

!!!Example stock AC on 09/07/01

Return to Top of Page

Gilligans Island Buys

! Based upon strategies from "Hit and Run Trading" by Jeff Cooper. Copyright M. Gordon Publishing.
! Gilligans Island - Buys - from Hit and Run Trading by Jeff Cooper.
! Stock must gap open to a new 2 month low.
! Stock must close at or in the top 50% of its daily range and equal to or above the open.
! The next day, buy 1/8 above todays high.

Range is Val([high], 1) - Val([low], 1).

High is Range * 0.50.

GapDown if Val([open], 1) < Val([low], 2).

TwoMonthLow if Val([low], 1) < LoVal([low], 60, 2).

PriceUp if Val([close], 1) >= (High + Val([low], 1)).

AboveOpen if Val([close], 1) >= Val([open], 1).

Buy if [close] >= Val([high], 1) + 0.125.

GilligansIslandBuy if GapDown and PriceUp and AboveOpen and Buy and TwoMonthLow.

!!!Example stock BMI on 09/06/01

Return to Top of Page

Gilligans Island Shorts

! Based upon strategies from "Hit and Run Trading" by Jeff Cooper. Copyright M. Gordon Publishing.
! Gilligans Island - Short - from Hit and Run Trading by Jeff Cooper.
! Stock must gap open to a new 2 month high.
! Stock must close at or in the lower 50% of its daily range and equal to or under the open.
! The next day, sell 1/8 under todays low.

Range is Val([high], 1) - Val([low], 1).

Low is Range * 0.50.

GapUp if Val([open], 1) > Val([high], 2).

TwoMonthHigh if Val([high], 1) > HiVal([high], 60, 2).

PriceDown if Val([close], 1) <= (Low + Val([low], 1)).

BelowOpen if Val([close], 1) <= Val([open], 1).

Short if [close] <= Val([low], 1) - 0.125.

GilligansIslandShortBuy if GapUp and PriceDown and BelowOpen and Short and TwoMonthHigh.

!!!Example stock ACTN on 09/06/2001

Return to Top of Page

Lizards Buy

! Based upon strategies from "Hit and Run Trading" by Jeff Cooper. Copyright M. Gordon Publishing.
! Lizards - buys - from Hit and Run Trading by Jeff Cooper.
! Day 1 open and close must be in the top 25% of the daily range.
! Day 1 low must be a 10 day Trading low.
! Today buy 1/8 above the day 1 high.

Range is Val([high], 1) - Val([low], 1).

High is Range * 0.75.

Top25 if Val([open], 1) >= (high + Val([low], 1)) and Val([close], 1) >= (high + Val([low], 1)).

Low if Val([low], 1) < LoVal([low], 11, 2). 

Buy if [close] >= Val([high], 1) + 0.125.

LizardBuy if Top25 and Low and Buy.

!!!Example stock ARLP on 09/10/01

Return to Top of Page

Lizards Short

! Based upon strategies from "Hit and Run Trading" by Jeff Cooper. Copyright M. Gordon Publishing.
! Lizards - short - from Hit and Run Trading by Jeff Cooper.
! Day 1 open and close must be in the bottom 25% of the daily range.
! Day 1 high must be a 10 day Trading high.
! Today sell 1/8 above the day 1 low.

Range is Val([high],1) - Val([low],1).

Low is Range * 0.25.

Bottom25 if Val([open],1)<=(Low + Val([low],1)) and Val([close],1)<=(Low + Val([low],1)).

High if Val([high],1) > HiVal([high],11,2). 

Sell if [close] <= Val([low],1) - 0.125.

LizardSell if Bottom25 and High and Sell.

!!!Example stock GRMN on 09/10/01

Return to Top of Page

Slingshots Buy

!!!! Jeff Cooper's Slingshots Buy
Breakout if val([high], 1) >= hival([high], 40, 1) and [low] < (val([low], 1) - 0.125).
Enter if iff([open] < (val([low], 1) - 0.125), [open], 0).

Return to Top of Page

Slingshots Sell

!!!! Jeff Cooper's Slingshots Sell
Breakout if val([low], 1) <= loval([low], 40, 1) and [high] > (val([high], 1) + 0.125).

Entersell if iff([open] < (val([low], 1) - 0.125), [open], 0).

Return to Top of Page

Stepping in front of Size

! Based upon strategies from "Hit and Run Trading" by Jeff Cooper. Copyright M. Gordon Publishing.
! Stepping in front of size - from Hit and Run Trading by Jeff Cooper

! 1. ADX reading above 30 and positive Directional Movement

ADX30PosDirMov if [ADX] > 30 and [DirMov] > 0.

! 2. Average Daily Volume less than 200,000 shares a day.

Average200Volume if [Volume ESA] < 200000.

!3. Stock must be Trading higher for the day.

TradingHigher if [high] > Val([high], 1).

SteppinginFrontofSize if ADX30PosDirMov and Average200Volume and TradingHigher.

!!!Example stock FUNC on 09/10/01

Return to Top of Page

Whoops Short

! Based upon strategies from "Hit and Run Trading" by Jeff Cooper. Copyright M. Gordon Publishing.
! Whoops! - Short - from Hit and Run Trading by Jeff Cooper.
! Stock must be Trading under its 10 and 50 day MA.
! The previous days close must be below the open.
! Todays open must be at least 1/4 point above yesrdays close.
! Sell short at 1/8 point below yesterdays close.

BelowMa if [close] < [St MA] and [close] < [IT MA].

PreviousClose if Val([close], 1) < Val([open], 1).

TodaysOpen if [open] >= Val([close], 1).

Sell if [close] <= Val([close], 1) -0.125.

WhoopsShort if BelowMa and PreviousClose and TodaysOpen and Sell.

!!!Example stock FAB on 09/10/01

Return to Top of Page